Qt 5.11 | Qt Location | Plane Spotter (QML) | Plane.qml Example File

Qt 5.11.3 Reference Documentation

# Plane.qml Example File

planespotter/Plane.qml

      /****************************************************************************
      **
      ** Copyright (C) 2017 The Qt Company Ltd.
      ** Contact: https://www.qt.io/licensing/
      **
      ** This file is part of the examples of the Qt Toolkit.
      **
      ** $QT_BEGIN_LICENSE:BSD$
      ** Commercial License Usage
      ** Licensees holding valid commercial Qt licenses may use this file in
      ** accordance with the commercial license agreement provided with the
      ** Software or, alternatively, in accordance with the terms contained in
      ** a written agreement between you and The Qt Company. For licensing terms
      ** and conditions see https://www.qt.io/terms-conditions. For further
      ** information use the contact form at https://www.qt.io/contact-us.
      **
      ** BSD License Usage
      ** Alternatively, you may use this file under the terms of the BSD license
      ** as follows:
      **
      ** "Redistribution and use in source and binary forms, with or without
      ** modification, are permitted provided that the following conditions are
      ** met:
      **   * Redistributions of source code must retain the above copyright
      **     notice, this list of conditions and the following disclaimer.
      **   * Redistributions in binary form must reproduce the above copyright
      **     notice, this list of conditions and the following disclaimer in
      **     the documentation and/or other materials provided with the
      **     distribution.
      **   * Neither the name of The Qt Company Ltd nor the names of its
      **     contributors may be used to endorse or promote products derived
      **     from this software without specific prior written permission.
      **
      **
      ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
      ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
      ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
      ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
      ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
      ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
      ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
      ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
      ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
      ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
      ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
      **
      ** $QT_END_LICENSE$
      **
      ****************************************************************************/

      import QtQuick 2.4
      import QtLocation 5.6

      // Plane.qml
      MapQuickItem {
          id: plane
          property string pilotName;
          property int bearing: 0;

          anchorPoint.x: image.width/2
          anchorPoint.y: image.height/2

          sourceItem: Grid {
              //...
              columns: 1
              Grid {
                  horizontalItemAlignment: Grid.AlignHCenter
                  Image {
                      id: image
                      rotation: bearing
                      source: "airplane.png"
                  }
                  Rectangle {
                      id: bubble
                      color: "lightblue"
                      border.width: 1
                      width: text.width * 1.3
                      height: text.height * 1.3
                      radius: 5
                      Text {
                          id: text
                          anchors.centerIn: parent
                          text: pilotName
                      }
                  }
              }

              Rectangle {
                  id: message
                  color: "lightblue"
                  border.width: 1
                  width: banner.width * 1.3
                  height: banner.height * 1.3
                  radius: 5
                  opacity: 0
                  Text {
                      id: banner
                      anchors.centerIn: parent
                  }
                  SequentialAnimation {
                      id: playMessage
                      running: false
                      NumberAnimation { target: message;
                          property: "opacity";
                          to: 1.0;
                          duration: 200
                          easing.type: Easing.InOutQuad
                      }
                      PauseAnimation  { duration: 1000 }
                      NumberAnimation { target: message;
                          property: "opacity";
                          to: 0.0;
                          duration: 200}
                  }
              }
          }
          function showMessage(message) {
              banner.text = message
              playMessage.start()
          }
      }